搭建环境
UNIX 标准环境下已预装 yacc、lex
Windows 使用免费替代品 bison、flex

运算符，+、-、*、/；整数；实数；换行符，输入完算式即刻换行就执行程序，所以换行符也是记号

 /* 文件 mycalc.l */
%{
#include <stdio.h>
#include "y.tab.h"

int 
yywrap(void)
{
  return 1;
}
%}
%%
 /* 本行之前叫`定义区块`，用来定义初始状态或者为正则表达式命名 */
 /* 这里的定义区块里放了 C 代码，其中如果缺失 yywrap 函数就必须手动链接 lex 的库文件，在不同环境下编译时会出现麻烦 */
"+"		return ADD;
"-"		return SUB;
"*"		return MUL;
"/"		return DIV;
"\n"	return CR;
([1-9][0-9]*)|0|([0-9]+\.[0-9]+) {
  double temp;
  sscanf(yytext, "%lf", &temp);
  yylval.double_value = temp;
  return DOUBLE_LITERAL;
}
[ \t] ;
. {
    fprintf(stderr, "lexical error. \n");
    exit(1);
}
 /* 规则区块，一个正则后跟若干空格，再跟 C 代码（动作 action），返回特征符 */
%%
 /* 本行以后叫`用户代码区块`，可编写任意 C 代码 */

 /* 文件 mycalc.y */
%{
#include <stdio.h>
#include <stdlib.h>
#define YYDEBUG 1 // 设置非 0 值开启 Debug 模式，可以看到运行时语法分析状态
%}
%union {
	int		int_value;
	double	double_value; // 声明`非终结符`类型，此类型的对立面是`终结符`
}
%token <double_value>	DOUBLE_LITERAL /* 值为 DOUBLE_LITERAL 的记号，类型为 <double_value>，double_value 来自上方 %union 集合的一个成员名 */
%token ADD SUB MUL DIV CR /* 记号类型 */
%type <double_value> expression term primary_expression /* 声明非终结符类型 */
%% /* 本行以后的区块叫`规则区块`，由语法规则和 C 编写的相应动作两部分组成 */
 /* 使用 BNF 规范编写语法规则，巴科斯范式，巴库斯-瑙尔范式，Backus Normal Form */
line_list
	: line
	| line_list line
	;
line
	: expression CR
	{
		printf(">>%lf\n", $1);
	}
	| error CR /* 简单的错误恢复机制 */
	{
		yyclearin; /* 丢弃预读的记号 */
		yyerrok; /* 通知 yacc 程序已经从错误状态恢复了 */
	}
	;
expression
	: term
	| expression ADD term
	{
		$$ = $1 + $3; // 记号值，$1 是 expression，$3 是 term，$2 不存在记号值，因为它是加法运算符 +，计算结果会赋给 $$ 保存在栈中
	}
	| expression SUB term
	{
		$$ = $1 - $3;
	}
	;
term
	: primary_expression
	| term MUL primary_expression
	{
		$$ = $1 * $3;
	}
	| term DIV primary_expression
	{
		$$ = $1 / $3;
	}
	;
primary_expression
	: DOUBLE_LITERAL
	;
%%
int
yyerror(char const *str)
{
	extern char *yytext;
	fprintf(stderr, "parser error near %s\n", yytext);
	return 0;
}

int main(void)
{
	extern int yyparse(void);
	extern FILE *yyin;

	yyin = stdin;
	if (yyparse()) {
		fprintf(stderr, "Error ! Error ! Error !\n");
		exit(1);
	}
}

% yacc -dv mycalc.y
% lex mycalc.l
% cc -o mycalc y.tab.c lex.yy.c -std=c89
// 使用 C89 https://stackoverflow.com/questions/27220759/linker-error-yacc-on-mac